4 ヒストリ関数
ここに記載されているすべての関数は、以下でサポートされています:
関数は追加情報なしでリストされています。 関数をクリックすると詳細が表示されます。
| 関数 | 説明 |
|---|---|
| change | 前回の値と最新の値の差分。 |
| changecount | 定義された評価期間内で隣接する値の変化回数。 |
| count | 定義された評価期間内の値の数。 |
| countunique | 定義された評価期間内のユニークな値の数。 |
| find | 定義された評価期間内で値の一致を検索。 |
| first | 定義された評価期間内の最初(最も古い)の値。 |
| firstclock | 定義された評価期間内の最初(最も古い)の値のタイムスタンプ。 |
| fuzzytime | パッシブエージェントの時刻がZabbixサーバー/プロキシの時刻とどれだけ異なるかをチェック。 |
| last | 最新の値。 |
| lastclock | 定義された評価期間内のN番目に新しい値のタイムスタンプ。 |
| logeventid | 最後のログエントリのイベントIDが正規表現に一致するかをチェック。 |
| logseverity | 最後のログエントリのログ重大度。 |
| logsource | 最後のログエントリのログソースが正規表現に一致するかをチェック。 |
| logtimestamp | N番目に新しいログアイテム値のログメッセージタイムスタンプ。 |
| monodec | 値が単調減少しているかをチェック。 |
| monoinc | 値が単調増加しているかをチェック。 |
| nodata | データが受信されていないかをチェック。 |
| percentile | 期間のPパーセンタイル(Pは3番目のパラメータで指定)。 |
| rate | 定義された期間内で単調増加カウンタの1秒あたりの平均増加率。 |
共通パラメータ
/host/keyは、ホストのアイテム履歴を参照する関数に共通する必須の第1パラメータです(sec|#num)<:time shift>は、ホストのアイテム履歴を参照する関数に共通する第2パラメータで、以下を意味します:
関数の詳細
関数パラメータに関する一般的な注意事項:
- 関数パラメータはカンマで区切ります
- オプションの関数パラメータ(またはパラメータの一部)は
<>で示します - 関数固有のパラメータは各関数で説明します
/host/keyおよび(sec|#num)<:time shift>パラメータは引用符で囲まないでください
change(/host/key)
前回の値と最新の値の差分。
サポートされる値の型: Float, Integer, String, Text, Log。
文字列の場合は、0 - 値が等しい; 1 - 値が異なる。
パラメータ: 共通パラメータを参照。
コメント:
- 数値の差分は、以下のような受信値の例で計算されます（「前回」と「最新」の値 = 差分）:
'1' と '5' =+4
'3' と '1' =-2
'0' と '-2.5' =-2.5。 - トリガーでは、急激なスパイク（またはドロップ）、カウンタリセット、数値状態の遷移を検出するのに便利です。
- 比較には abs も参照してください。
例:
change(/host/system.uptime)<0 #前回の値からシステムの稼働時間がマイナスになった（再起動を示す）
change(/host/system.cpu.load[all,avg1])>2 #CPUロード（1分間）が前回の値から2以上増加した
change(/host/vfs.fs.size[/,free])<-1G #チェック間で空きディスク容量が1GB以上減少したchangecount(/host/key,(sec|#num)<:time shift>,<mode>)
定義された評価期間内で隣接する値間の変化回数。
サポートされる値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照
- mode (ダブルクォーテーションで囲む必要あり) - 指定可能な値: all - すべての変化をカウント(デフォルト); dec - 減少のみカウント; inc - 増加のみカウント
コメント:
- 数値以外の値の型の場合、modeパラメータは無視されます。
- トリガーでは、頻繁な状態変化(不安定さを示す)を検出するのに便利です。
例:
changecount(/host/icmpping,10m)>5 #10分間にpingの状態が5回以上変化した
changecount(/host/vfs.file.contents["/sys/class/net/eth0/operstate"],1h)>5 #eth0のoperational stateが1時間に5回以上変化した
changecount(/host/proc.num[httpd],15m)>10 #httpdプロセス数が15分間に10回以上変化した
changecount(/host/key,#10,"inc") #直近10個の値の中で値が増加した回数(隣接値と比較)
changecount(/host/key,24h,"dec") #現在までの直近24時間で値が減少した回数(隣接値と比較)count(/host/key,(sec|#num)<:time shift>,<operator>,<pattern>)
定義された評価期間内の値の数。
サポートされる値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照
- operator（二重引用符で囲む必要があります）
サポートされる
operator:
eq - 等しい（integer、floatのデフォルト）
ne - 等しくない
gt - より大きい
ge - 以上
lt - より小さい
le - 以下
like（string、text、logのデフォルト） - パターンを含む場合に一致（大文字・小文字を区別）
bitand - ビット単位AND
regexp -patternで指定された正規表現に大文字・小文字を区別して一致
iregexp -patternで指定された正規表現に大文字・小文字を区別せず一致 - pattern - 必要なパターン（文字列引数は二重引用符で囲む必要があります）
コメント:
- Floatのアイテムは2.22e-16の精度で一致判定されます。
- like はinteger値のoperatorとしてはサポートされていません。
- like と bitand はfloat値のoperatorとしてはサポートされていません。
- string、text、log値では、eq、ne、like、regexp、iregexp のoperatorのみがサポートされます。
- operatorとして bitand を使用する場合、4番目の
patternパラメータは '/' で区切られた2つの数値、number_to_compare_with/mask として指定できます。 count() は値と mask の「ビット単位AND」を計算し、その結果を number_to_compare_with と比較します。 「ビット単位AND」の結果が number_to_compare_with と等しい場合、その値がカウントされます。
number_to_compare_with と mask が等しい場合は、mask のみを指定できます（'/' なし）。 - operatorとして regexp または iregexp を使用する場合、4番目の
patternパラメータには通常の正規表現またはグローバル（'@' で始まる）正規表現を指定できます。 グローバル正規表現の場合、大文字・小文字の区別はグローバル正規表現の設定から継承されます。 regexp照合のために、float値は常に '.' の後に小数点以下4桁で表現されます。 また、大きな数値では10進表現（データベースに保存）と2進表現（Zabbix serverで使用）の違いにより、小数点以下4桁目に影響する場合があることにも注意してください。
例:
count(/host/icmpping,30m,,"0")>5 #30分間でpingが5回を超えて失敗している
count(/host/key,10m,"like","error") #直近10分間の現在までの値のうち、'error' を含む値の数
count(/host/key,10m,,12) #直近10分間の現在までの値のうち、'12' に等しい値の数
count(/host/key,10m,"gt",12) #直近10分間の現在までの値のうち、'12' を超える値の数
count(/host/key,#10,"gt",12) #直近10個の値のうち、現在までで '12' を超える値の数
count(/host/key,10m:now-1d,"gt",12) #現在から24時間前の時点を基準に、その10分前から24時間前までの間で '12' を超えていた値の数
count(/host/key,10m,"bitand","6/7") #直近10分間の現在までの値のうち、下位3ビットに '110'（2進数）を持つ値の数
count(/host/key,10m:now-1d) #現在から24時間前の時点を基準に、その10分前から24時間前までの間の値の数countunique(/host/key,(sec|#num)<:time shift>,<operator>,<pattern>)
定義された評価期間内の一意な値の数。
サポートされる値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照
- operator（二重引用符で囲む必要があります）。
サポートされる
operator:
eq - 等しい（integer、float のデフォルト）
ne - 等しくない
gt - より大きい
ge - 以上
lt - より小さい
le - 以下
like（string、text、log のデフォルト） - パターンを含む場合に一致（大文字・小文字を区別）
bitand - ビット単位AND
regexp -patternで指定された正規表現に大文字・小文字を区別して一致
iregexp -patternで指定された正規表現に大文字・小文字を区別せず一致 - pattern - 必要なパターン（文字列引数は二重引用符で囲む必要があります）
コメント:
- Floatのアイテムは 2.22e-16 の精度で一致します。
- integer値では、like はoperatorとしてサポートされません。
- float値では、like および bitand はoperatorとしてサポートされません。
- string、text、log の値では、eq、ne、like、regexp、iregexp のoperatorのみがサポートされます。
- operatorとして bitand を使用する場合、4番目の
patternパラメータは '/' で区切られた2つの数値、number_to_compare_with/mask として指定できます。countunique() は値と mask の「ビット単位AND」を計算し、その結果を number_to_compare_with と比較します。 「ビット単位AND」の結果が number_to_compare_with と等しい場合、その値はカウントされます。
number_to_compare_with と mask が等しい場合は、mask のみを指定できます（'/' は不要）。 - operatorとして regexp または iregexp を使用する場合、4番目の
patternパラメータには通常の正規表現、またはグローバル（'@' で始まる）正規表現を指定できます。 グローバル正規表現の場合、大文字・小文字の区別はグローバル正規表現の設定を継承します。 regexp照合のために、float値は常に '.' の後に小数点以下4桁で表現されます。 また、大きな数値では10進表現（データベースに保存）と2進表現（Zabbix serverで使用）の違いにより、小数点以下4桁目に影響する場合があることにも注意してください。
例:
countunique(/host/key,10m) #直近10分間の一意な値の数
countunique(/host/key,10m,"like","error") #直近10分間で 'error' を含む一意な値の数
countunique(/host/key,10m,,12) #直近10分間で '12' に等しい一意な値の数
countunique(/host/key,10m,"gt",12) #直近10分間で '12' より大きい一意な値の数
countunique(/host/key,#10,"gt",12) #直近の10個の値の範囲内で '12' より大きい一意な値の数
countunique(/host/key,10m:now-1d,"gt",12) #現在から24時間前の時点を基準に、その10分前から24時間前までの間で '12' より大きかった一意な値の数
countunique(/host/key,10m,"bitand","6/7") #直近10分間で下位3ビットに '110'（2進数）を持つ一意な値の数
countunique(/host/key,10m:now-1d) #現在から24時間前の時点を基準に、その10分前から24時間前までの間の一意な値の数find(/host/key,(sec|#num)<:time shift>,<operator>,<pattern>)
定義された評価期間内で一致する値を検索します。
サポートされる値の型: Float, Integer, String, Text, Log。
戻り値: 1 - 見つかった場合; 0 - それ以外。
パラメータ:
- 共通パラメータを参照
- sec または #num (任意) - 指定しない場合は最新の値がデフォルトで使用されます
- operator (二重引用符で囲む必要があります)
サポートされる
operators:
eq - 等しい (integer, float のデフォルト)
ne - 等しくない
gt - より大きい
ge - 以上
lt - より小さい
le - 以下
like (string, text, log のデフォルト) -patternで指定された文字列を含む場合に一致します (大文字・小文字を区別)
bitand - ビット単位AND
regexp -patternで指定された正規表現との大文字・小文字を区別する一致
iregexp -patternで指定された正規表現との大文字・小文字を区別しない一致 - pattern - 必要なパターン (文字列引数は二重引用符で囲む必要があります);
operatorが regexp, iregexp の場合は Perl Compatible Regular Expression (PCRE) 正規表現
コメント:
- 複数の値が処理される場合、一致する値が少なくとも1つあれば '1' が返されます。
- integer 値では like は演算子としてサポートされません。
- float 値では like と bitand は演算子としてサポートされません。
- string、text、log 値では、eq、ne、like、regexp、iregexp 演算子のみがサポートされます。
- 演算子として regexp または iregexp を使用する場合、4番目の
patternパラメータには通常の正規表現、または グローバル (先頭が '@') 正規表現を指定できます。 グローバル正規表現の場合、大文字・小文字の区別はグローバル正規表現の設定から継承されます。
例:
find(/host/key,10m,"like","error") #現在までの直近10分間で 'error' を含む値を検索
find(/host/agent.version,,"like","beta")=1 #Zabbix エージェントがベータ版であり、アップグレードが必要
find(/host/log[/var/log/nginx/access.log],,"regexp"," 500 ")=1 #内部Webサーバーエラーが見つかったfirst(/host/key,sec<:time shift>)
定義された評価期間内の最初(最も古い)の値。
サポートされている値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照
last()も参照。
例:
first(/host/key,1h) #現在までの直近1時間で最も古い値を取得firstclock(/host/key,sec<:time shift>)
定義された評価期間内の最も古い値のタイムスタンプ。
サポートされる値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照してください。
指定された期間にデータが収集されていない場合、関数はエラーで失敗します。
lastclock()も参照してください。
例:
firstclock(/host/key,1h) #直近1時間の最も古い値のタイムスタンプを取得
firstclock(/host/key,1h:now-24h) #1日前の直近1時間の最も古い値のタイムスタンプを取得fuzzytime(/host/key,sec)
パッシブエージェントの時刻が、Zabbixサーバー/プロキシの時刻とどの程度異なるかを確認します。
サポートされる値の型: Float, Integer。
戻り値: 1 - パッシブアイテムの値（タイムスタンプとして扱われる）と Zabbixサーバー/プロキシのタイムスタンプ（値収集時の時刻）の差が sec 秒以下の場合; 0 - それ以外。
パラメータ:
- 共通パラメータを参照してください。
コメント:
- 通常、ローカル時刻が Zabbixサーバー のローカル時刻と同期していることを確認するために、'system.localtime' アイテムとともに使用されます。 注:'system.localtime' は、Zabbixエージェントでは パッシブチェック として設定されている必要があります。Zabbixエージェント 2 では、アクティブチェックとして設定することもできます。
vfs.file.time[/path/file,modify]キーとともに使用して、ファイルが長時間更新されていないことを確認することもできます。- この関数は、複雑なトリガー条件式（複数のアイテムが関係するもの）での使用は推奨されません。予期しない結果を引き起こす可能性があるためです（時刻差は最新のメトリクスで測定されます）。例えば、
fuzzytime(/Host/system.localtime,60s)=0 or last(/Host/trap)<>0のような場合です。
例:
fuzzytime(/host/system.localtime,5m)=0 #クライアントのローカル時刻が Zabbixサーバー/プロキシの時刻と 5 分以上異なる
fuzzytime(/host/system.localtime,5m)=0 and nodata(/host/system.localtime,10m)=0 #クライアントのローカル時刻が Zabbixサーバー/プロキシの時刻と 5 分以上異なる（アイテムがデータ送信を停止していないことも確認）last(/host/key,<#num<:time shift>>)
最新の値。
サポートされている値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照
- #num (オプション) - N番目に新しい値
コメント:
- ハッシュタグ付きの期間(#N)は、他の多くの関数とは異なる動作をすることに注意してください。
例えば:
last(/host/key)は常にlast(/host/key,#1)と等しい;last(/host/key,#3)は3番目に新しい値(最新の3つの値ではない)。 - 1秒以内に2つ以上の値が履歴に存在する場合、Zabbixは値の正確な順序を保証しません。
- first()も参照してください。
例:
last(/host/key) #最新の値を取得
last(/host/key,#2) #1つ前の値を取得
last(/host/key,#1)<>last(/host/key,#2) #最新の2つの値が異なるlastclock(/host/key,<#num<:time shift>>)
定義された評価期間内でN番目に新しい値のタイムスタンプ。
サポートされる値の型: Float, Integer, String, Text, Log。
パラメータ:
- 共通パラメータを参照;
- #num (省略可能) - N番目に新しい値。
指定された期間にデータが収集されていない場合、またはN番目の値が収集されていない場合、関数はエラーで失敗します。
firstclock()も参照してください。
例:
lastclock(/host/key) #最新値のタイムスタンプを取得
lastclock(/host/key,#2) #2番目に新しい値のタイムスタンプを取得
now()-lastclock(/host/heartbeat.item)>300 #ハートビートアイテムが更新されてから5分以上経過している
lastclock(/host/system.cpu.load[all,avg1])-lastclock(/host/system.cpu.load[all,avg1],#2)>300 #直近2つの値の更新間隔が5分を超えている
((now()-lastclock(/host/system.cpu.load[all,avg1])<120 and last(/host/system.cpu.load[all,avg1])>5)) #CPU値が高く、値が新しい（2分未満）logeventid(/host/key,<#num<:time shift>>,<pattern>)
最後のログエントリのイベントIDが正規表現に一致するかどうかを確認します。
サポートされている値の型: ログ。
戻り値: 0 - 一致しない; 1 - 一致する。
パラメータ:
- 共通パラメータを参照
- #num (省略可能) - 最新からN番目の値
- pattern (省略可能) - 必要なパターンを記述する正規表現、Perl互換正規表現 (PCRE)スタイル（文字列引数はダブルクォートで囲む必要があります）
例:
logeventid(/host/eventlog[Security],,"4625")=1 #IDが"4625"（認証失敗）に一致するログエントリが見つかった
logeventid(/host/eventlog[System],,"6008|41")=1 #IDが"6008"または"41"に一致するログエントリが見つかったlogseverity(/host/key,<#num<:time shift>>)
最後のログエントリのログ重大度。
サポートされている値の型: ログ。
戻り値: 0 - デフォルトの重大度; N - 重大度(整数、Windowsイベントログに便利: 1 - Information, 2 - Warning, 4 - Error, 7 - Failure Audit, 8 - Success Audit, 9 - Critical, 10 - Verbose)。
パラメータ:
- 共通パラメータを参照
- #num (オプション) - 最新からN番目の値
ZabbixはWindowsイベントログのInformationフィールドからログ重大度を取得します。
例:
logseverity(/host/log[/var/log/syslog],10m)>3 #重大度が"3"を超えるログエントリが見つかった
logseverity(/host/eventlog[System],10m)=4 #重大度が"Error"に等しいログエントリが見つかったlogsource(/host/key,<#num<:time shift>>,<pattern>)
最後のログエントリのログソースが正規表現に一致するかどうかを確認します。
サポートされている値の型: ログ。
戻り値: 0 - 一致しない; 1 - 一致する。
パラメータ:
- 共通パラメータを参照
- #num (省略可能) - N番目に新しい値
- pattern (省略可能) - 必要なパターンを記述する正規表現、Perl互換正規表現 (PCRE)スタイル（文字列引数はダブルクォーテーションで囲む必要があります）
通常、Windowsイベントログで使用されます。
例:
logsource(/host/eventlog[Application],,"MSSQLSERVER")=1 #ソースが"MSSQLSERVER"に一致するログエントリが見つかった
logsource(/host/eventlog[System],,"Service Control Manager")=1 #ソースが"Service Control Manager"に一致するログエントリが見つかった
logsource(/host/eventlog[System],,"Service Control Manager")=1 and logeventid(/host/eventlog[System],,"7031")=1 #ソースが"Service Control Manager"に一致し、イベントIDが"7031"に一致するログエントリが見つかったlogtimestamp(/host/key,<#num<:time shift>>)
N番目に新しいログアイテム値のログメッセージのタイムスタンプ。
サポートされる値の型: Log。
パラメータ:
- 共通パラメータを参照;
- #num (省略可能) - N番目に新しい値。
コメント:
- タイムシフトの計算は、ログメッセージのタイムスタンプではなく、アイテム値のクロックに基づいて行われます;
- 次の場合、関数はエラーで失敗します:
- ログタイプ以外のアイテムが受信された場合;
- 指定された期間にデータが収集されていない場合;
- N番目の値が収集されていない場合;
- ログメッセージにタイムスタンプ値が含まれていない場合。
例:
logtimestamp(/host/key) #最新のログメッセージのタイムスタンプを取得
logtimestamp(/host/key,#2) #2番目に新しいログメッセージのタイムスタンプを取得
logtimestamp(/host/key,#3:now-1d) #1日前の3番目に新しいログメッセージのタイムスタンプを取得monodec(/host/key,(sec|#num)<:time shift>,<mode>)
値が単調減少しているかどうかを確認します。
サポートされている値の型: 整数。
戻り値: 1 - 期間内のすべての要素が連続して減少している場合; 0 - それ以外の場合。
パラメータ:
- 共通パラメータを参照
- mode (ダブルクォーテーションで囲む必要あり) - weak (すべての値が前の値以下; デフォルト) または strict (すべての値が減少している)
例:
monodec(/host/system.swap.size[all,free],60s) + monodec(/host2/system.swap.size[all,free],60s) + monodec(/host3/system.swap.size[all,free],60s) #スワップの空き容量が減少したホスト数を計算
monodec(/host/proc.num[nginx],10m,"strict")=1 #nginxプロセス数が10分間単調減少しているmonoinc(/host/key,(sec|#num)<:time shift>,<mode>)
値が単調増加しているかどうかを確認します。
サポートされている値の型: 整数。
戻り値: 1 - 期間内のすべての要素が連続して増加している場合; 0 - それ以外の場合。
パラメータ:
- 共通パラメータを参照
- mode (ダブルクォーテーションで囲む必要あり) - weak (すべての値が前の値以上; デフォルト) または strict (すべての値が増加している)
例:
monoinc(/host/system.localtime,#3,"strict")=0 #システムのローカル時刻が一貫して増加していない
monoinc(/host/vfs.dir.count[/mnt/data/logs],24h,"weak")=0 #ファイル数が24時間停滞している場合にトリガー(増加が期待される)nodata(/host/key,sec,<mode>)
データが受信されていないことを確認します。
サポートされる値の型: Integer, Float, Character, Text, Log。
戻り値: 1 - 定義された期間中にデータが受信されなかった場合; 0 - それ以外。
パラメータ:
- 共通パラメータを参照してください
- sec - history syncerプロセスはこの関数を30秒ごとにしか計算しないため、期間は30秒未満にできません。
nodata(/host/key,0)は許可されていません - mode - strict（二重引用符付き）に設定すると、この関数はプロキシの可用性の影響を受けなくなります（詳細はコメントを参照）
コメント:
- プロキシによって監視される 'nodata' トリガーは、デフォルトでプロキシの可用性の影響を受けます。プロキシが利用不可になった場合、接続が復旧した直後に 'nodata' トリガーが発火することはなく、遅延した期間のデータはスキップされます。
パッシブプロキシでは、接続の復旧が15秒を超え、かつ2秒以上経過してから行われた場合に抑制が有効になります。
アクティブプロキシでは、接続の復旧が15秒を超えてから行われた場合に抑制が有効になります。
プロキシの可用性の影響を無効にするには、3番目のパラメータを使用します。例:
nodata(/host/key,5m,"strict")。この場合、評価期間（5分間）にデータがなければ、その期間の経過後すぐにこの関数は発火します。 - この関数は、1番目のパラメータで指定された期間内に以下のいずれかに該当する場合、エラーを表示します:
- データがなく、Zabbixサーバーが再起動された場合
- データがなく、メンテナンスが完了した場合
- データがなく、アイテムが追加または再有効化された場合。 - エラーは、トリガーの設定にある Info 列に表示されます。
- Zabbixサーバー、プロキシ、エージェントの間に時刻のずれがある場合、この関数は正しく動作しない可能性があります。 関連項目: 時刻同期の要件。
例:
nodata(/host/agent.ping,5m)=1 #Zabbixエージェントから5分間データが受信されなかった場合にトリガーpercentile(/host/key,(sec|#num)<:time shift>,percentage)
期間のPパーセンタイル。P（パーセンテージ）は3番目のパラメータで指定します。
サポートされる値の型：Float、Integer。
パラメータ:
- 共通パラメータを参照
- percentage - 小数点以下4桁までの0から100（両端を含む）の浮動小数点数
例:
percentile(/host/net.if.in[eth0,bytes],1h,95)>1000000 #1時間のネットワーク入力（バイト/秒）の95パーセンタイルがしきい値（例：1MB/s）を超えた
percentile(/host/system.cpu.util,5m,95)>80 #CPU使用率のユーザータイムパーセンテージの95パーセンタイルが80を超えた
percentile(/host/icmppingsec[192.168.0.2],15m,95)>0.15 #ほとんどのレイテンシ測定値は150ms未満だが、上位5%の値が定期的な遅延を示唆している
percentile(/host/net.if.in[eth0,bytes],1h,50) #1時間の受信ネットワークトラフィックの50パーセンタイル（中央値）を計算する。これはavg()（平均値）とは異なる結果となる。percentileは外れ値を考慮しないため
(percentile(/host/net.if.in[eth0,bytes],1h,50)+percentile(/host/net.if.in[eth0,bytes],1h,51))/2 #1時間の値が偶数個の場合に正確な中央値を計算するrate(/host/key,sec<:time shift>)
指定した期間内の単調増加カウンターの1秒あたりの平均増加量。
サポートされる値の型: Float, Integer。
パラメータ:
- 共通パラメータを参照
PromQLの'rate'に機能的に対応。
例:
rate(/host/key,30s) #30秒間の単調増加が20の場合、この関数は0.67を返します。
rate(/host/net.if.in[eth0,bytes],5m)>500000 #過去5分間でeth0の受信インターフェーストラフィックレートが500KB/sを超えた
rate(/host/app.requests.count,1m)>100 #リクエストカウントカウンターが直近1分間で1秒あたり100リクエストを超えて増加したサポートされているすべての関数を参照してください。